PPINT

=PPINT(pp_array, [a], [b])

Download the Template

In the template file, navigate to the Polynomials worksheet to see the PPINT function in action.

Description

The definite integral of a polynomial, \(P(x) = \int_a^bp(x)dx\), can be calculated exactly using POLYINT. Likewise, a Piecewise Polynomial, which is made up of separate polynomial segments, can be integrated exactly, using POLYINT on individual segments.

A piecewise polynomial is defined only within the bounds [x₁,x_N] where the first column of the data structure array is the column vector of N break points. For the purposes of integration, values outside that domain are considered to be zero.

The following example is a piecewise polynomial data structure described within the PPVAL function documentation.

Integrating this example from a=-10 to b=100 is the same as integrating it from 0 to 15, since all values outside of [0,15] are treated as zero.

=LET(
    pp_array, {0,0,2,-1,1,10;4,0,0,-5,0,126;10,-1,5,1,4,-54;15,0,0,0,0,0},
    PPINT(pp_array)
)

Result: 528.5833

Cumulative Integration

If the optional cumulative parameter is TRUE, the function returns the cumulative integral corresponding to each segment where P(x₁)=0 and P(x_k) is:

If a and b are not specified, then the cumulative integral of the piecewise polynomial from a=x₁ to b=x_N is:

For the example above:

=LET(
    pp_array, {0,0,2,-1,1,10;4,0,0,-5,0,126;10,-1,5,1,4,-54;15,0,0,0,0,0},
    PPINT(pp_array,,,TRUE)
)

Result: {0; 154.667; 550.667; 528.5833}

Lambda Formula

This code for using PPINT in Excel is provided under the License as part of the LAMBDA Library, but to use just this function, you may copy the following code directly into your spreadsheet.

/**
* Definite Integral of a Piecewise Polynomial from a to b
*/
PPINT = LAMBDA(pp_array,[a],[b],[cumulative],
LET(doc,"https://www.vertex42.com/lambda/ppint.html",
    breaks,INDEX(pp_array,0,1),
    pieces,ROWS(breaks)-1,
    coeffs,DROP(pp_array,-1,1),
    a,IF(OR(ISBLANK(a),a<INDEX(breaks,1)),INDEX(breaks,1),a),
    b,IF(OR(ISBLANK(b),b>INDEX(breaks,pieces+1)),INDEX(breaks,pieces+1),b),
    areas,SCAN(0,SEQUENCE(pieces+1),LAMBDA(acc,i,
    IF(i=1,0,LET(
        x_1,INDEX(breaks,i-1),
        x_2,INDEX(breaks,i),
        IF(NOT(AND(a<INDEX(breaks,i),b>INDEX(breaks,i-1))),acc+0,
            acc+POLYINT(CHOOSEROWS(coeffs,i-1),,MAX(0,a-x_1),MIN(b,x_2)-x_1)
        )
    )))),
    IF(cumulative=TRUE,areas,INDEX(areas,pieces+1,1))
));

Name: PPINT
Description: Integrate a Piecewise Polynomial
Arguments: pp_array, a, b, cumulative
Function:
[in the works]

PPINT Examples

Example: Integration of a Cubic Spline

The CSPLINE function returns a cubic piecewise polynomial. For this example we'll use the function \(f(x)=x\sin(x)/4+4\). The exact integral between 0 and 6π is (70.6858347...) so we'll see how well a cubic spline works with only 30 segments (31 points) beetween 0 and 6π.

=LET(
    xs, LINSPACE(0,6*PI(),31),
    ys, xs/4*SIN(xs)+4,
    spline, CSPLINE(xs,ys),
    PPINT(spline)
)

Result: 70.706534
Error: 0.0207

The default cubic spline function calculates slopes using only forward, backward, and central difference approximations. But, we can improve the accuracy using PDIFF to obtain higher-order estimates of the slopes.

=LET(
    xs, LINSPACE(0,6*PI(),31),
    ys, xs/4*SIN(xs)+4,
    slopes, PDIFF(xs,ys,1,3),
    spline, CSPLINE(xs,ys,,slopes),
    PPINT(spline)
)

Result: 70.678297
Error: -0.0075

Note: The trapezoidal rule using TRAPZ for these same 31 points results in 70.8419 with an error of 0.156.

See Also

TRAPZ, PPVAL, CSPLINE, LINSPACE, PDIFF, POLYINT